Wikipedia
ウィキペディアZig (プログラミング言語)の記事があります。

本書は、Zigのチュートリアルです。 Zigは、堅牢で最適かつ再利用可能なソフトウェアを維持するための汎用システムプログラミング言語およびツールチェインです[1]。 Zigは、アンドリュー・ケリー( Andrew Kelley )によって設計され、静的で強い型付けで型推論とジェネリックプログラミングをサポートします。

概要編集

Zigは、2016年2月に発表された比較的若いプログラミング言語で[2]、2022年9月現在の最新バージョンは 0.9.1 で、pre-release と位置づけられています[3]。このため Hello world ですら、バージョン間で互換性がなくなることもあり、今後もリリースバージョンまでは言語仕様やライブラリーおよびツールチェインの仕様が変更される可能性があります。

Hello world の変遷編集

Zig Language Referenceの、Hello worldの変遷(新しい順)。

master@2022-07-17[4]
0.8.1に同じ
0.9.1[5]
0.8.1に同じ
0.8.1[6]
const std = @import("std");
pub fn main() !void {
    const stdout = std.io.getStdOut().writer();
    try stdout.print("Hello, {s}!\n", .{"world"});
}
{}{s}[7]
0.7.1[8]
const std = @import("std");
pub fn main() !void {
    const stdout = std.io.getStdOut().writer();
    try stdout.print("Hello, {}!\n", .{"world"});
}
s/outStream/writer/
0.6.0[9]
const std = @import("std");
pub fn main() !void {
    const stdout = std.io.getStdOut().outStream();
    try stdout.print("Hello, {}!\n", .{"world"});
}
初期化の初期値から try がなくなった。
0.4.0[10]
0.2.0に同じ
0.5.0[11]
const std = @import("std");
pub fn main() !void {
    // If this program is run without stdout attached, exit with an error.
    const stdout_file = try std.io.getStdOut();
    // If this program encounters pipe failure when printing to stdout, exit
    // with an error.
    try stdout_file.write("Hello, world!\n");
}
stdout_filevar から const に変更された。
0.3.0[12]
0.2.0に同じ
0.2.0[13]
const std = @import("std");
pub fn main() !void {
    // If this program is run without stdout attached, exit with an error.
    var stdout_file = try std.io.getStdOut();
    // If this program encounters pipe failure when printing to stdout, exit
    // with an error.
    try stdout_file.write("Hello, world!\n");
}
0.1.1[14]
const io = @import("std").io;
pub fn main() -> %void {
    %%io.stdout.printf("Hello, world!\n");
}

環境準備編集

Zigは、2022年7月の時点で pre-release の段階にあり、インストール手順も何度か変わっているので、まずは https://ziglang.org/learn/getting-started/ を参照し、最新のインストール手順を確認してください。また、ローカルのパッケージデータベースをパッケージシステムのリポジトリと同期を取り、鮮度の高い状態を維持するよう心がけてください。これは、インストール後も同じですし、zigに限ったことでもありません。

オンラインコンパイル実行環境編集

ローカルにコンパイル実行環境を作るのが困難な場合、あるいは手間を掛けずにコンパイルと実行を試してみたい場合。そんな場合には、オンラインコンパイル実行環境を使うことも検討に値します。

Zig Playground
公式のオンラインコンパイル実行環境です。
フォーマッターも利用できます。
Wandbox
複数のプログラミン言語に対応しており、Zigにも対応したいます。

両方とも test 機能を使えないのが残念です。

パッケージ マネージャー によるインストール編集

nightly の Zigを使いたい場合でない限り、お使いのOSやディストリビューションでサポートされているパッケージ マネージャを使ってインストールする事をお勧めします。

Windows編集

Zig は、Chocolateyパッケージシステムが対応しています。

> choco install zig
macOS編集

macOS では、HomebrewMacPortsが対応しています。

最新とタグ付けされたリリース
# brew install zig
Git の master ブランチの最新ビルド
# brew install zig --HEAD
MacPorts
# port install zig
FreeBSD編集
pkg
# pkg install zig
ports
# make -C /usr/ports/lang/zig all install clean
GNU/Linuxのディストリビューション編集

いわゆるLinuxは、Linux(ここではOSカーネル)と、FSFがHurdカーネルのために設計・開発したGNUユーザーランド(OSの基本機能を提供するソフトウェアの集合)を組合わせたものです。 このように、LinuxカーネルとGNUユーザーランドを組合わせたソフトウェアプラットフォームをGNU/Linuxと呼びます[15]

Fedora 36編集
# dnf install zig

ソースコードからのビルド編集

Zig は、ソースコードが Github の https://github.com/ziglang/zig.git で公開されているので、必要に応じてソースコードからビルドすることができます。 Zigは、セルフホスティング[16]なので、最初にバイナリーを入手してブートストラップするか、クロスビルドしたバイナリーを持込むか、パッケージシステムからインストールし、ターゲットでセルフコンパイル出来る状態を作る方法があります(FreeBSDのPortsが行っているのは、まさにこれです)。

ビルド方法こそ頻繁に内容が変わるので、個別具体的な手順は述べませんが、zig はコンパイラーであるとともにツールチェインでもあり、ビルドシステムも内包しているので、

zig build
とすると build.zig ファイルに書かれているレシピにしたがって自動的にビルドが進行します(ストレージとメモリーと時間に余裕を見る必要があります)。

zig コマンド編集

Zig の処理系 zig という1つのコマンドで、コンパイラーだけでなく、アーカイバー・C/C++コンパイラーやテストフレームワーク・フォーマッター・ビルドツールなどのツールチェインが統合されています。

zig コマンドを tcsh から実行
% uname -a
FreeBSD localhost 13.1-STABLE FreeBSD 13.1-STABLE #0 6480563d0: Thu Aug 25 19:34:52 JST 2022     sakura@localhost:/usr/obj/usr/src/amd64.amd64/sys/SV1G amd64
% zig version
0.9.1
% cat hello.zig
const std = @import("std");
const print = std.io.getStdOut().writer().print;
pub fn main() !void {
    try print("Hello, {s}!\n", .{"world"});
}
% zig run hello.zig
Hello, world!

zig コマンドの runサブコマンドは、当該ソースファイルの(ソースコードの変更やキャッシュ クリアーなど必要性があれば)コンパイルとコンパイルの成果物の実行を行います。これを「インタープリター風」と称することがありますが、二回目からはソースファイルを変更したりキャッシュをクリアーしない限りコンパイルのオーバーヘッドが不要で、キャッシュ内の実行形式が実行されるなど、ビルドツール/ビルドシステムとしての特徴が際立ち、逐次解釈的な要素は希薄(皆無)です。crystali/interactive サブコマンドのように、真に対話的に実行する処理系も既にあるので、ビルドシステムの簡易呼出しとインタープリターを混同すべきではありません。

基礎篇編集

[TODO:書くべき項目を並べてみましたが、例えば「値と型」だけでも網羅的に書いていくとコンテンツの分量が爆発するのが目に見えているので、過剰になったらリファレンス篇に移動するなどの方法で、各節はコンパクトさを心がけたい]

コメント編集

Zigでは、// から行末までがコメントです。 C言語の /* … */ のスタイルの複数行に渡るコメントはありません。 これは、コードの各行を文脈に関係なくトークン化できるようにするためです。

hello.zig
// hello.zig:
const std = @import("std"); // 先頭に @ が付く関数は組込み関数です
pub fn main() !void {
   try std.io.getStdOut().writeAll("Hello, World!\n");\
}
Builtin Functions

Docコメント編集

Zigでは、/// から始まるコメントは特別なコメントで、Docコメント( Doc comments )と呼ばれます。 Docコメントは特定の場所にしか許されません。式の途中や非Docコメントの直前など、予想外の場所にdocコメントがあると、コンパイルエラーになります。

[TODO:サンプルコードと整形結果]

トップレベルDocコメント編集

Zigでは、//! から始まるコメントは特別なコメントで、トップレベルDocコメント( Top-Level Doc Comments )と呼ばれます。 コンテナレベルのドキュメントのように、直後のドキュメントに属さないユーザードキュメントに、トップレベルDocコメントを使います。

[TODO:サンプルコードと整形結果]

DocコメントおよびトップレベルDocコメントは、コンパイル時に zig build-exe -femit-docs ソースファイル.zig の様に、-femit-docs をあたえると、 docs/ 以下にドキュメントが生成されます。

値と型編集

[TOD0:整数浮動小数点数bool文字列unionstructenum配列ベクトルスライスポインター・ゼロビットな型, 関連する組込み関数]

formatを伴うprintと値と型
pub fn main() !void {
    const print = @import("std").io.getStdOut().writer().print;
    try print(" (1) = {}\n", .{42});
    try print(" (2) = {}\n", .{0x17});
    try print(" (3) = {}\n", .{0o17});
    try print(" (4) = {}\n", .{0b0100101});
    try print(" (5) = {}\n", .{1e222});
    try print(" (6) = {}\n", .{3.1415926536});
    try print(" (7) = {}\n", .{'c'});
    try print(" (8) = {c}\n", .{'c'});
    try print(" (9) = {s}\n", .{"abcdef"});
    try print("(10) = {}, {}\n", .{ 111, 999 });
    try print("(11) = {1}, {0}\n", .{ 111, 999 });
    try print("(12) = {1s}, {0}\n", .{ 111, "abc" });
    try print("(13) = {0d}, {0b}, {0o}, {0x}, {0X}\n", .{ 123 });
}
実行結果
 (1) = 42
 (2) = 23
 (3) = 15
 (4) = 37
 (5) = 1.0e+222
 (6) = 3.1415926536e+00
 (7) = 99
 (8) = c
 (9) = abcdef
(10) = 111, 999
(11) = 999, 111
(12) = abc, 111
(13) = 123, 1111011, 173, 7b, 7B
print()の前の、tryは単項演算子です。
try は、右の式のエラーユニオン式を評価します。もしエラーであれば、同じエラーで現在の関数から戻ます。そうでない場合は、式はラップされていない値になります。
エラーユニオン型( Error Union Type )を返す関数は、try単項演算子かcatch二項演算子で、値とエラーを弁別する必要があります(tryあるいはcatchがないと、コンパイル時にエラーになります)。
An error occurred:
/tmp/playground726918707/play.zig:3:10: error: error is ignored. consider using `try`, `catch`, or `if`    print(" (1) = {}\n", .{42});
                                                                                                                ^
print()の様に、標準ライブラリの format()を使う関数は、書式化文字列タプル(匿名 struct ) .{ … } を引数にします。C言語のような、可変引数ではなくタプルを使うので[17]、プレースホルダーがない場合でも、空のタプル.{} は必須です。
書式化文字列
通常の文字列ですが {} で囲まれたプレスホルダーが、タプルの当該順位の値(を書式化した文字列)に置換わります。
書式化文字列の中で { あるいは } 自身を使いたいときには、{{ あるいは }} と二文字重ねます。
タプル
書式化文字列のプレースホルダーのよって、参照と文字列化される値のタプルです。
2つ以上の値を渡す場合は、第二引数を .{ 1, 2, 3 } の様にカンマ区切りのタプルにします( {} の前の . (点)を忘れがちですが、型の省略を意味し必須です)。
基本的に、左から順にプレスホルダーにタプルの値が左から与えられますが、{0} {1} の書式で参照する引数の順位を明示できます。
書式指定と併用する時は、 print("? = {1s}, {0}\n", .{ 111, "abc" }) の様に順位が先、書式指定文字が後になります。
この機能は言語(自然言語)によって異なる語順を吸収することに使えそうですが、fmtの第一引数は comptime 修飾子がついていて変数にはできません。
数値(整数浮動小数点数)や文字リテラルと文字列リテラルがあり、整数はいくつかの異なる基数表現が、浮動小数点数は指数表現と小数表現があります。
文字と文字列は明確に異なり、リレラルでは ’A’ が文字、 ”ABC” が文字列です。
嫌な予感がした人の直感は正解です。Zig では、文字列は第一級オブジェクトではなく文字(u8)の配列で、関数から返すときはアロケーターと defer の連携などで記憶域の寿命と値の妥当性を「プログラマー」が担保する必要があります。また、GoのGCはありません。CrystalのASTを操作できるマクロもありませんし、Rustの所有権も、C++のスマートポインターもありません。
このことは、C言語なみのプログラマー任せのメモリー管理を文字列以外でも強いられることを意味していますが、zig(コマンド)のソースコードを読むと、複数の型でアロケーターを使い分け、スタック上のインスタンス(のハードウェア起因のスコープ)を使い分けられることを実践で証明しているので、pre-releaseから、initial-releasまでの間に、安定化・定式化が図られることを期待します。

[TODO:master/lib/std/fmt.zigを観て書いています。参照すべき標準ライブラリのドキュメントを出来たら/仕様が安定したら見直し]

プリミティブ型編集

プリミティブ型( Primitive Types )[18]
相当するC言語の型 説明
i8 int8_t 符号付き8ビット整数
u8 uint8_t 符号無し8ビット整数
i16 int16_t 符号付き16ビット整数
u16 uint16_t 符号無し16ビット整数
i32 int32_t 符号付き32ビット整数
u32 uint32_t 符号無し32ビット整数
i64 int64_t 符号付き64ビット整数
u64 uint64_t 符号無し64ビット整数
i128 __int128 符号付き128ビット整数
u128 unsigned __int128 符号無し128ビット整数
isize intptr_t 符号付きポインターサイズ整数
usize uintptr_t, size_t 符号無しポインターサイズ整数
c_short short C言語とのABI互換性のため
c_ushort unsigned short C言語とのABI互換性のため
c_int int C言語とのABI互換性のため
c_uint unsigned int C言語とのABI互換性のため
c_long long C言語とのABI互換性のため
c_ulong unsigned long C言語とのABI互換性のため
c_longlong long long C言語とのABI互換性のため
c_ulonglong unsigned long long C言語とのABI互換性のため
c_longdouble long double C言語とのABI互換性のため
f16 _Float16 16ビット浮動小数点数(仮数10ビット) IEEE-754-2008 binary16
f32 float 32ビット浮動小数点数(仮数23ビット) IEEE-754-2008 binary32
f64 double 64ビット浮動小数点数(仮数52ビット) IEEE-754-2008 binary64
f80 double 80ビット浮動小数点数(仮数64ビット) IEEE-754-2008 80ビット拡張精度
f128 _Float128 128ビット浮動小数点数(仮数112ビット) IEEE-754-2008 binary64
bool bool true または false
anyopaque void 型消去されたポインター
void (該当なし) 0ビット型
noreturn (該当なし) break, continue, return, unreachable, and while (true) {} の型
type (該当なし) 型の型
anyerror (該当なし) エラーコード
comptime_int (該当なし) コンパイル時に既知の値に対してのみ許可される整数リテラルの型。
comptime_float (該当なし) コンパイル時に既知の値に対してのみ許可される浮動小数点リテラルの型。
上記の整数型に加え、任意のビット幅の整数を参照するには、識別子としてiまたはuに続けて数字を用いることができます。例えば、識別子 i7 は符号付き7ビット整数を意味します。この表現の整数型に許される最大ビット幅は65535です。

プリミティブ値編集

プリミティブ型( Primitive Values )[19]
名前 説明
truefalse bool
null optional型を null に設定するために使用されます。
undefined 値を不定にするために使用されます。

文字列リテラルとUnicodeコードポイントリテラル編集

構文(EBNF)
STRINGLITERALSINGLE = "\"" string_char* "\"" skip
STRINGLITERAL = STRINGLITERALSINGLE
              | ( line_string                skip )+

ox80_oxBF = [#x80-#xBF]
oxF4 = '\xF4'
ox80_ox8F = [#x80-#x8F]
oxF1_oxF3 = [#xF1-#xF3]
oxF0 = '\xF0'
ox90_0xBF = [#x90-#xBF]
oxEE_oxEF = [#xEE-#xEF]
oxED = '\xED'
ox80_ox9F = [#x80-#x9F]
oxE1_oxEC = [#xE1-#xEC]
oxE0 = '\xE0'
oxA0_oxBF = [#xA0-#xBF]
oxC2_oxDF = [#xC2-#xDF]

(* From https://lemire.me/blog/2018/05/09/how-quickly-can-you-check-that-a-string-is-valid-unicode-utf-8/ *)
mb_utf8_literal = oxF4      ox80_ox8F ox80_oxBF ox80_oxBF
                | oxF1_oxF3 ox80_oxBF ox80_oxBF ox80_oxBF
                | oxF0      ox90_0xBF ox80_oxBF ox80_oxBF
                | oxEE_oxEF ox80_oxBF ox80_oxBF
                | oxED      ox80_ox9F ox80_oxBF
                | oxE1_oxEC ox80_oxBF ox80_oxBF
                | oxE0      oxA0_oxBF ox80_oxBF
                | oxC2_oxDF ox80_oxBF

ascii_char_not_nl_slash_squote = [\000-\011\013-\046-\050-\133\135-\177]

char_escape = "\\x" hex hex
            | "\\u{" hex+ "}"
            | "\\" [nr\\t'"]
char_char = mb_utf8_literal
          | char_escape
          | ascii_char_not_nl_slash_squote
string_char = char_escape
            |  [^\\"\n]

line_string = ( "\\\\" [^\n]* [ \n]* )+
[20]
文字列リテラル編集

文字列リテラルは、ヌル終端バイト配列への定数型単一項目ポインターです。文字列リテラルの型は、長さとヌル終端であるという事実の両方をコード化しているため、スライスとヌル終端ポインターの両方に強制することが可能です。文字列リテラルを再参照すると配列に変換されます[21]

Zigにおける文字列のエンコーディングは、事実上UTF-8であると仮定されています。ZigのソースコードはUTF-8でエンコードされているので、ソースコードの文字列リテラル内に現れる非ASCIIバイトは、そのUTF-8の意味をZigのプログラム内の文字列の内容に引き継ぎ、コンパイラがそのバイトを修正することはありません。ただし、UTF-8以外のバイトを文字列リテラルに埋め込むことは可能で、その場合は \xNN 記法を使用します[21]

Unicodeコードポイントリテラル編集

Unicodeコードポイントリテラルの型は comptime_int で整数リテラルと同じです。すべてのエスケープシーケンスは、文字列リテラルと Unicodeコードポイントリテラルの両方において有効です[21]

他の多くのプログラミング言語では、Unicodeコードポイントリテラルは「文字リテラル」と呼ばれます。しかし、Unicode仕様の最近のバージョン(Unicode 13.0時点)では、「文字」の正確な技術的定義は存在しません。Zigでは、Unicodeコードポイントリテラルは、Unicodeのコードポイントの定義に対応します。

エスケープシーケンス編集
エスケープシーケンス( Escape Sequences )[22]
エスケープシーケンス 名称
\n Newline
\r Carriage Return
\t 水平タブ
\\ バックスラッシュ自身
\' シングルクォーテーション
\" ダブルクォーテーション
\xNN 16進8ビットバイト値(2桁)
\u{NNNNNN} 16進数 Unicode コードポイント UTF-8 符号化(1桁以上)
註:有効なUnicodeポイントの最大値は0x10ffffです。

複数行にまたがる文字列リテラル編集

文字列リテラルを、エスケープ記号がなく複数行にまたがって書くことができます。複数行の文字列リテラルを開始するには、\\ トークンを使用します。コメントと同じように、文字列リテラルは行末まで続きます。行の終わりは文字列リテラルに含まれません。ただし、次の行が \\ で始まる場合は、改行が追加され文字列リテラルが続行されます。

複数行にまたがる文字列リテラル
const print = @import("std").io.getStdOut().writer().print;
const message =
    \\文字列リテラルを、エスケープ記号がなく複数行にまたがって書くことができます。
    \\複数行の文字列リテラルを開始するには、\\ トークンを使用します。
    \\コメントと同じように、文字列リテラルは行末まで続きます。
    \\行の終わりは文字列リテラルに含まれません。
    \\ただし、次の行が \\ で始まる場合は、改行が追加され文字列リテラルが続行されます。
;

pub fn main() !void {
    try print("message = {s}", .{message});
}
実行結果
message = 文字列リテラルを、エスケープ記号がなく複数行にまたがって書くことができます。
複数行の文字列リテラルを開始するには、\\ トークンを使用します。
コメントと同じように、文字列リテラルは行末まで続きます。
行の終わりは文字列リテラルに含まれません。
ただし、次の行が \\ で始まる場合は、改行が追加され文字列リテラルが続行されます

comptime編集

Zigでは、コンパイル時に式が既知かどうかという概念を重要視しています。

このコードはコンパイルエラーになります。

定数の初期値が関数の戻値だとエラー
fn mul(x: usize, y: usize) usize {
    return x * y;
}

pub fn main() void {
    const len : usize = mul(3, 4);
    const ary: [len]i32 = undefined;
    _ = ary;
}
コンパイル結果
An error occurred:
/tmp/playground130713503/play.zig:7:17: error: unable to evaluate constant expression
    const ary: [len]i32 = undefined;
「定数式が評価できない」と宣っています。
C++であれば、constexprが適用なケースですが、Zigでは次のような解決方法を取ります。下記コードはエラーになりません。
comptimeを追加しコンパイル時に実行
fn mul(x: usize, y: usize) usize {
    return x * y;
}

pub fn main() void {
    const len : usize = comptime mul(3, 4); // mul の前に comptime を追加
    const ary: [len]i32 = undefined;
    _ = ary;
}
変更点は mul() の呼出しを comptime で修飾しただけです。comptime は、修飾子式をコンパイル時に実行する修飾子で、式の中でコンパイル時に未定な値が参照されると、エラーとなります。ここでは、数リテラル同士の商を求めているので、コンパイル時値が確定できます。
_ = ary は、「未使用変数」をサプレッスするときのイディオムです。

テスト編集

Zigは、言語仕様とツールチェインの両方でテストをサポートしています。

構文(EBNF)
test-decl = [ doc_comment ] "test" [ STRINGLITERALSINGLE ] block
[20]
if.zig
const std = @import("std");
const expect = std.testing.expect;

test "if expr" {
    const f = true;
    var x: usize = 5;
    x += if (f) 10 else 20;
    try expect(x == 15);
}

test "if stmt" {
    const f = true;
    var x: isize = 10;
    if (!f) {
        x += 10;
    } else {
        x -= 20;
    }
    try expect(x == -10);
}
コマンドライン
% zig test if.zig
All 2 tests passed.
fdiv-inf-nan.zig
const std = @import("std");
const expect = std.testing.expect;

fn fdiv(n: f64, d: f64) f64 {
    return n / d;
}

const inf = std.math.inf(f64);
const nan = std.math.nan(f64);

test "fdiv 1" {
    try expect(fdiv(123.0, 111.1) == 123.0 / 111.1);
}

test "fdiv 2" {
    try expect(fdiv(123.0, 0.0) == inf);
}

test "fdiv 3" {
    try expect(fdiv(0.0, 0.0) == nan);
}
コマンドライン
% zig version
0.9.1
% zig test fdiv-inf-nan.zig
Test [3/3] test "fdiv 3"... FAIL (TestUnexpectedResult)
/usr/local/lib/zig/std/testing.zig:303:14: 0x204c1b in std.testing.expect (test)
    if (!ok) return error.TestUnexpectedResult;
             ^
/tmp/zig/fdiv-inf-nan.zig:20:5: 0x204d97 in test "fdiv 3" (test)
    try expect(fdiv(0.0, 0.0) == nan);
    ^
2 passed; 0 skipped; 1 failed.
error: the following test command failed with exit code 1:
zig-cache/o/9ea24daf8934909606f2d1c0cde0e0d0/test /usr/local/bin/zig

変数編集

Zigでは、変数は名前を持った連続したメモリ領域で、型を持ちます。 変数は、宣言が必要です。

Zigでは型に名前を付けるためにも変数が使われます。

型を保持するconst変数の例
const Complex = struct {
    real: f64,
    imag: f64,
};

const Colour = enum {
    red,
    green,
    blue,
};

const Number = union {
    int: i64,
    float: f64,
};
構文(EBNF)
var-decl = ( "const" | "var" ) IDENTIFIER [ ":" type-expr ] [ byte-align ] [ link-section ] [ "=" expr ] ";"
[20]
実際は const は、型が省略でき、var は、型が省略できず、両方とも初期化が必須ないので[23]
var-decl = const-var-decl | var-var-decl
const-var-decl = "const" IDENTIFIER [ ":" type-expr ] [ byte-align ] [ link-section ] "=" expr ";"
var-var-decl = "var" IDENTIFIER ":" type-expr [ byte-align ] [ link-section ] "=" expr ";"
と意味論も加味するとなります。
var 変数の場合は、不定値としてプリミティブ値の undefined で初期化することができます[24]
undefinedは、任意の型に強制( be coerced )することができます。一旦これが起こると、値がundefinedであることを検出することができなくなります。 undefinedは、値が何にでもなり得ることを意味し、型によれば無意味なものでさえもあり得ることを意味します。英語で undefinedは "Not a meaningful value. Using this value would be a bug. The value will be unused, or overwritten before being used."(意味のない値。この値を使うとバグになる。この値は使われないか、使われる前に上書きされるでしょう)という意味です(ただしローカル変数が使われないと、error: unused local variable となります)。

const 変数編集

キーワード const で宣言された変数は、必ず初期化が必要で、宣言以降は値を変更することはできません。 const 変数の宣言のとき型が省略されると、初期値から型をコンパイラーが決めてくれます(型推論)。

const print = @import("std").io.getStdOut().writer().print;
pub fn main() !void {
    const i = 0;
    try print("i = {}\n", .{i});
}
実行結果
i = 0
ここでは printi が const 変数です。

[TODO:組込み関数 @import() の解説]

var 変数編集

キーワード var で変数を宣言するときも初期化は必須です。またいつでも値を変更することはできます。 var 変数の宣言では、型を省略することはできません。

const print = @import("std").io.getStdOut().writer().print;
pub fn main() !void {
    var i : isize = 0;
    try print("i = {}\n", .{i});
    i = 12;
    try print("i = {}\n", .{i});
    i *= i;
    try print("i = {}\n", .{i});
}
実行結果
i = 0
i = 12
i = 144
ここでは i が var 変数です。

識別子編集

変数の識別子は、外部スコープの識別子をシャドーイングすることは許されません[25]

外部スコープの識別子をシャドーイングすることは許されません
const x = 0;
pub fn main() !void {
    var x : isize = 1;
}
コンパイル結果
An error occurred: /tmp/playground248241835/play.zig:3:9: error: local shadows declaration of 'x'
/tmp/playground248241835/play.zig:1:1: note: declared here

識別子は英数字かアンダースコアで始まり、英数字かアンダースコアがいくつでも続くことができます[25]。また、キーワードと重なってはいけません[25]

外部ライブラリとのリンクなど、これらの要件に適合しない名前が必要な場合は、@""構文を使用することができます。

const @"identifier with spaces in it" = 0xff;
const @"1SmallStep4Man" = 112358;
const c = @import("std").c;
pub extern "c" fn @"error"() void;
pub extern "c" fn @"fstat$INODE64"(fd: c.fd_t, buf: *c.Stat) c_int;
const Color = enum {
    red,
    @"really red",
};
const color: Color = .@"really red";
  1. スペースを含んだ識別子
  2. 数字から始まる識別子
  3. C言語バインドAPI
  4. C言語の外部リンケージで error 関数を外部参照宣言
  5. C言語の外部リンケージで int fstat(fd_t fd, Stat *buf) 関数を外部参照宣言
  6.  
  7.  
  8. スペースを含んだ列挙メンバーを定義
  9.  
  10. スペースを含んだ列挙メンバーを参照
https://ziglang.org/documentation/master/#Identifiers から引用

整数編集

整数リテラル編集

構文(EBNF)
INTEGER = "0b" bin_int skip
        | "0o" oct_int skip
        | "0x" hex_int skip
        |      dec_int skip

skip = ([ \n] | line_comment)*

bin = "0" | "1"
bin_ = [ '_' ] bin
oct = "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7"
oct_ = [ '_' ] oct
hex = "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
    | "a" | "b" | "c" | "d" | "e" | "f"
    | "A" | "B" | "C" | "D" | "E" | "F"
hex_ = [ '_' ] hex
dec =  "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
dec_ = [ '_' ] dec
bin_int = bin bin_*
oct_int = oct oct_*
dec_int = dec dec_*
hex_int = hex hex_*
[20]
2進数・8進数・16進数はそれぞれ 0b0o0x を前置します。
他の多くの言語と異なり 0 の次の文字は小文字が必須で、大文字は受け付けません。

実行時整数値編集

浮動小数点数編集

浮動小数点数リテラル編集

構文(EBNF)
FLOAT = "0x" hex_int "." hex_int [ ( "p" | "P" ) [ "-" | "+" ] dec_int ] skip
      |      dec_int "." dec_int [ ( "e" | "E" ) [ "-" | "+" ] dec_int ] skip
      | "0x" hex_int ( "p" | "P" ) [ "-" | "+" ] dec_int skip
      |      dec_int ( "e" | "E" ) [ "-" | "+" ] dec_int skip
[20]
10進数のほか、16進数の浮動小数点数リテラルに対応していますが、2進数・8進数の浮動小数点数リテラルには対応していません。
16進数の浮動小数点数リテラルも、指数部は10進数です。

浮動小数点演算編集

制御構造編集

Zigは、やや関数型プログラミング言語の影響を受けており、多くの構文が値を持ちます。 Zigの制御構造の多くは式構文と文構文を持ちます(例外は #switch で式構文しかありません)。

以下、Kotlin#条件分岐から、一部の例を移植しました。

分岐編集

Zigには、#if#switch の2つの分岐構文があります。

if編集

Zigでは、if は値を分岐する if式 とブロックを分岐する if文 があります。

構文(EBNF)
if-expr = if-prefix expr [ "else" [ payload ] expr ]
if-prefix = "if" "(" expr ")" [ ptr-payload ]
payload = "|" IDENTIFIER "|"
ptr-payload = "|" [ "*" ] IDENTIFIER "|"

if-statement = if-prefix block-expr [ "else" [ payload ] statement ]
             | if-prefix assign-expr ( ; | "else" [ payload ] statement )
block-expr = [ block-label ] block
block-label = IDENTIFIER ":"
block = "{" statement* "}"
assign-expr = expr [ assign-op expr ]
assign-op = "+=" | "-=" | "*=" | "/=" ...(略)
[20]
if式の例
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() void {
    const i = 0;

    if (i == 0)
        print("zero\n", .{}) // ここに ; があるとエラーになります。
    else
        print("non zero\n", .{});

    print(if (i == 0)
        "Zero\n"
    else
        "Non zero\n", .{});
}
実行結果
zero
Zero
8行目に ; があると if 式がそこで終わってしまい、else と結合できません。ブロックを使えば…
if文に変更
    if (i == 0) {
        print("zero\n", .{}); // ブロック中ならば ; があってもエラーになりません。
    } else {
        print("non zero\n", .{});
    }
と ; を使うことができます[26]
条件不成立でelseを省略すると編集

if式で、条件が成立せずelseを省略されたとき、式の値は void となります。

条件不成立でelseを省略すると
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() void {
    print("if (false) 1 => {}\n", .{ if (false) 1 });
}
実行結果
if (false) 1 => void
条件式に整数を使うと
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() void {
    const i = 0;

    if (i) {
        print("not zero", .{});
    }
}
コンパイルエラー
An error occurred: /tmp/playground3080235970/play.zig:7:9: error: expected type 'bool', found 'comptime_int'
    if (i) {
        ^
Zigでは、if に限らず、条件式は、boolオプショナル型あるいはエラーユニオン型でなければいけません。
    if (i != 0) {
とします。
オプショナル型を条件としたif編集

ifの条件式にはオプショナル型( ?T )を使うことが出来ます。この場合は、通常の値のほか null を想定でき、null に出会った場合は else 節が実行されます。

[TODO:コード例]

エラーユニオン型を条件としたif編集

ifの条件式にはエラーユニオン型( !T )を使うことが出来ます。この場合は、通常の値のほかエラーコードを想定でき、エラーコードに出会った場合は else |err| 節が実行され、err がエラーコードです。

[TODO:コード例]

switch編集

Zigでは、switch は式で値を返します。switch文はありません。switch-prong(分岐先)の値の型は一致している必要があります。

構文(EBNF)
switch-expr = "switch" "(" expr ")" "{" switch-prong-list "}"
switch-prong-list = (switch-prong "," )* [ switch-prong ]
switch-prong = switch-case "=>" [ ptr-payload ] assign-expr
switch-case = switch-item ( "," switch-item )* [ "," ] | "else"
switch-item = expr [ "..." expr ]
[20]
switch.zig
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() void {
    const mes = "a";

    switch (mes) {
        "a" => {
            print("定数で初期化しているので、", .{});
            print("mesはa\n", .{});
        },
        "b" => print("mesはb\n", {}),
        "c", "d", "e" => print("mesはcかdかe\n", .{}),
        else => print("mesはそれ以外", .{}),
    }

    // switch 式の値を使った等価なコード

    print(switch (mes) {
        "a" => blk: {
            print("定数で初期化しているので、", .{});
            break :blk "mesはa";
        },
        "b" => "mesはb",
        "c", "d", "e" => "mesはcかdかe",
        else => "mesはそれ以外",
    }, .{});
}
実行結果
定数で初期化しているので、mesはa
定数で初期化しているので、mesはa
ブロックの値を返すときの書き方が独特で、ラベル blk はキーワードではありませんが慣習化しつつあるようです。

反復編集

Zigには、#while#for の2つの反復構文があります。

while編集

while は、条件が成立しているあいだ続く式あるいはブロックを繰返します。 if 同様、while 式を反復する while式 とブロックを反復する while文 があります。

構文(EBNF)
loop-expr = [ "inline" ] ( for-expr | while-expr )
while-expr = while-prefix expr [ "else" [ payload ] expr ]
while-prefix = "while" "(" expr ")" [ ptr-payload ] [ while-continue-expr ]
while-continue-expr = ":" "(" assign-expr ")"

while-statement = while-prefix block-expr [ "else" [ pay-load ] statement ]
                | while-prefix assign-expr ( ; | "else" [ payload ] statement )
多くの構文要素は if と共通しているので #if の構文も参照してください[20]
Zigも、pythonのように else を伴うことのできる while です。
while.zig
pub fn main() !void {
    var i: usize = 1;
    while (i < 50) : (i += 1) {
        try print("{}! == {}\n", .{ i, fib(i) });
    }
}

fn fib(n: usize) usize {
    return if (n < 2) n else fib(n - 1) + fib(n - 2);
}

const print = std.io.getStdOut().writer().print;
const std = @import("std");
実行結果
An error occurred:
1! == 1
2! == 1
3! == 2
4! == 3
5! == 5
6! == 8
7! == 13
8! == 21
9! == 34
10! == 55
11! == 89
12! == 144
13! == 233
14! == 377
15! == 610
16! == 987
17! == 1597
18! == 2584
19! == 4181
20! == 6765
21! == 10946
22! == 17711
23! == 28657
24! == 46368
25! == 75025
26! == 121393
27! == 196418
28! == 317811
29! == 514229
30! == 832040
31! == 1346269
32! == 2178309
33! == 3524578
34! == 5702887
35! == 9227465
36! == 14930352
37! == 24157817
38! == 39088169
39! == 63245986
    while (i < 50) : (i += 1) {
        try print("{}! == {}\n", .{ i, fib(i) });
    }
    while (i < 50) {
        try print("{}! == {}\n", .{ i, fib(i) });
        i += 1;
    }
と等価で、追加の式はC言語の for (;;) の三項目にあたります。
while-with-else.zig
const print = std.io.getStdOut().writer().print;
const std = @import("std");

pub fn main() !void {
    var i: usize = 0;
    while (i < 5) : (i += 1) {
        try print("{} ", .{i});
    } else {
        try print("done!\n", .{});
    }
    i = 0;
    while (i < 50) : (i += 1) {
        try print("{} ", .{i});
        if (i == 10) {
            try print("break!\n", .{});
            break;
        }
    } else {
        try print("done!\n", .{});
    }
}
実行結果
0 1 2 3 4 done!
0 1 2 3 4 5 6 7 8 9 10 break!
while のループを「完走」すると、else 以降が実行されます。
もし break などで中断されると、else 以降は実行されません。
ラベル付きwhile編集

whileループにラベルを付けると、ネストしたループ内からのbreakやcontinueから参照できます[27]

ラベル付きwhile
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() !void {
    var i: u16 = 0;
    var j: u16 = 0;
    outer: while (i < 15) : (i += 1) {
       j = 0;
        while (j < 15) : (j += 1) {
            if (i == 7 and j == 11) {
                break :outer;
            }
        }
    }
    try print("i = {}, j = {}\n", .{ i, j });
}
実行結果
i = 7, j = 11
オプショナル型を条件としたwhile編集

ifと同じように、whileループは条件としてオプショナル型の値を受け取り、ペイロードをキャプチャすることができます。null に遭遇した場合、ループは終了します[28]

while 式に |x| 構文がある場合、while 条件はオプショナル型(あるいは次で述べるエラーユニオン型)でなければなりません(この x かキャプチャされたペイロードです)。

オプショナル型を条件としたwhile
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() void {
    var sum: u32 = 0;
    while (sequence()) |n| {
        sum += n;
    }
    print("sum = {}\n", .{sum});
}

fn sequence() ?u32 {
    const S = struct {
        var x: u32 = 5;
    };
    return if (S.x == 0) null else blk: {
        S.x -= 1;
        break :blk S.x;
    };
}
実行結果
sum = 10
エラーユニオン型を条件としたwhile編集

ifと同じように、whileループは条件としてエラーユニオン型の値を受け取り、ペイロードをキャプチャすることができます。エラーコードに遭遇した場合、ループは終了します[29]

while 式に |x| 構文がある場合、while 条件はエラーユニオン型(あるいは前で述べたオプショナル型)でなければなりません(この x かキャプチャされたペイロードです)。

while 式に else |x| 構文がある場合、while 条件にエラーユニオン型が必要です。

エラーユニオン型を条件としたwhile
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() void {
    var sum: u32 = 0;
    while (sequence()) |n| {
        sum += n;
    } else |err| {
        print("err = {}\n", .{err});
    }
    print("sum = {}\n", .{sum});
}

fn sequence() !u32 {
    const S = struct {
        var x: u32 = 5;
    };
    return if (S.x == 0) error.ReachedZero else blk: {
        S.x -= 1;
        break :blk S.x;
    };
}
実行結果
err = error.ReachedZero 
sum = 10
inline while編集

whileループはインライン化することができる。これにより、ループが展開され、コンパイル時にしかできないこと、例えば、型をファーストクラスの値として使用することなどができるようになります[30]

[TODO:コード例]

for編集
構文(EBNF)
for-statement = for-prefix block-expr [ "else" statement ]
              | for-prefix assign-expr ( ; | "else" statement )
for-prefix = "for" "(" expr ")" ptr-index-payload
ptr-index-payload = "|" [ "*" ] IDENTIFIER ( "," IDENTIFIER )? "|"

for-expr = for-prefix expr [ "else" expr ]
[20]
for-ary.zig
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() void {
    const int = i16;
    const ary = [_]int{ 1, 5, 4, 6, 4, 9 };
    var sum: int = 0;

    for (ary) |n, i| {
        print("n = {}, i = {}\n", .{ n, i });
        sum += n;
    }
    print("sum = {}\n", .{sum});

    var ary2 = ary;

    for (ary2) |*r| {
        r.* += 10;
    }
    for (ary2) |n| {
        print("{}, ", .{n});
    }
}
実行結果
n = 1, i = 0
n = 5, i = 1
n = 4, i = 2
n = 6, i = 3
n = 4, i = 4
n = 9, i = 5
sum = 29
11, 15, 14, 16, 14, 19,
for-str.zig
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() void {
    const str = "simple string";

    for (str) |c| {
        print("{c} ", .{c});
    }
}
実行結果
s i m p l e   s t r i n g
ラベル付きfor編集

ラベル付きfor( Labeled for )とは、ラベルを伴った for ループでラベルも for 構文の一部です。for ループにラベルを付けると、ネストしたループ内からのbreakやcontinueから参照できます[31]

ラベル付きfor
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() void {
    var x :usize = undefined;
    var y :usize = undefined;

    loop_top: for ("Hello") |co, i| {
        for ("World") |ci, j| {
            if (co == ci) {
                print("c = '{c}'({}, {})\n", .{ ci, i, j });
                x = i;
                y = j;
                break :loop_top;
            }
        }
    }
    print("x = {}, y = {}\n", .{x, y});
}
実行結果
c = 'l'(2, 3) 
x = 2, y = 3
inline for編集

Forループはインライン化することができます。これにより、ループが展開され、コンパイル時にしかできないこと、例えば、型をファーストクラスの値として使用することなどができるようになります。インライン化されたforループのキャプチャ値とイテレータ値は、コンパイル時既知です[32]

inline for
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() void {
    var x :usize = undefined;
    var y :usize = undefined;

    loop_top: inline for ("Hello") |co, i| {
        inline for ("World") |ci, j| {
            if (co == ci) {
                print("c = '{c}'({}, {})\n", .{ ci, i, j });
                x = i;
                y = j;
                break :loop_top;
            }
        }
    }
    print("x = {}, y = {}\n", .{x, y});
}
実行結果
c = 'l'(2, 3) 
x = 2, y = 3

[TODO:PrimaryTypeExprの説明:型システムで言及すべき?]

関数編集

Zigでは、サブルーチンやプロシージャーを関数と呼びます。 プログラムのエントリーポイントの main() も関数です。

Zigの関数の引数は、const で宣言された変数と同じくイミュータブルです。 ミュータブルにする方法はありません。

構文(EBNF)
top-level-decl = [ "inline" | "noinline" ] FnProto ( ";" | block )
FnProto = "fn" [ IDENTIFIER ] "(" param-decl-list ")" [ byte-align ] [ link-section ] [ call-conv ] [ "!" ] type-expr
param-decl-list = ( param-decl "," )* [ param-decl ]
param-decl = [ doc_comment ] [ "noalias" | "comptime" ] [ IDENTIFIER ":" ] param-type | "..."
param-type = "anytype" | type-expr
type-expr = [ prefix-type-op ] ErrorUnionExpr
prefix-type-op = "?"
             | "anyframe" "->"
             | slice-type-start ( byte-align | "const" | "volatile" | "allowzero" )*
             | ptr-type-start ( "align" "(" expr [ ":" INTEGER ":" INTEGER) ] ")"  | "const" | "volatile" | "allowzero" )*
             | array-type-start
slice-type-start = "[" [ ":" expr ] "]"
byte-align = "align" "(" expr ")"
link-section = "linksection" "(" expr ")"
call-conv = "callconv" "(" expr ")"
ptr-type-start = "*" | "**" | "[" "*" [ "c" | ":" expr ] "]"
array-type-start = "[" expr [ ":" expr ] "]"
top-level-declは関数宣言の他、変数宣言なども含みますが、関数宣言部分を抜粋しました[20]
関数の例
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() !void {
    print("{}\n", .{div(1, 0)});
    print("{}\n", .{div(0, 0)});
}

fn div(f1: f64, f2: f64) f64 {
    return f1 / f2;
}
実行結果
inf
-nan
他のプログラミング言語をご存じの方なら、関数 div() が前方参照になっているのは大丈夫なのか?と思われるかもしれません。
Zigではトップレベルの識別子は処理系が参照解決(とシグネチャーを含めた型の一致の確認)を引受けてくれます。

エラー編集

Zigでは、エラー( Errors )も1つの型です[33]

エラー集合型編集

エラー集合型( Error Set Type )は、enum のようなものです。同じエラー名を複数回宣言することは可能で、宣言した場合は同じ整数値が割り当てられます[34]。 コンパイル全体のユニークなエラー値の数が、エラー集合型のサイズを決定するはずです。しかし、いま[35]は u16 になるようにハードコーディングされています。 サブセットからスーパーセットへエラーを強制することができます。

構文(EBNF)
error-set-decl = "error" "{" identifier-list "}"
[20]
エラー集合型の例
const std = @import("std");
const print = std.io.getStdOut().writer().print;

const FileOpenError = error{
    AccessDenied,
    OutOfMemory,
    FileNotFound,
};

const AllocationError = error{
    OutOfMemory,
};

pub fn main() !void {
    print("AllocationError.OutOfMemory == FileOpenError.OutOfMemory ⇒ {}\n", .{AllocationError.OutOfMemory == FileOpenError.OutOfMemory});
}
実行結果
AllocationError.OutOfMemory == FileOpenError.OutOfMemory ⇒ true
エラー集合和編集

2つのエラー集合型は、|| 二項演算子で和集合を得ることが出来ます。

グローバルエラー集合型編集

anyerror は、グローバルエラー集合を参照します。これは、コンパイルユニット全体のすべてのエラーを含むエラー集合です。これは他のすべてのエラー集合の上位セットで、どのエラー集合の下位セットでもありません。

任意のエラー集合をグローバルエラー集合に強制することができ、グローバルエラー集合のエラーを非グローバルエラー集合に明示的にキャストすることができます。この場合、言語レベルのアサートが挿入され、エラー値が宛先のエラー集合に実際に含まれていることが確認されます。

グローバルエラー集合は、コンパイラがコンパイル時にどのようなエラーが起こりうるかを知ることができないため、一般に避けるべきです。コンパイル時にエラー集合を知っていた方が、生成されるドキュメントや有用なエラーメッセージ(例えば switch で起こりうるエラー値を忘れてしまうなど)に有利です。

エラーユニオン型編集

エラーセット型と正常型を二項演算子 ! で結合して、エラーユニオン型( Error Union Type )にすることができます。

var error_or_value: AllocationError ! u16 = 10;

エラーユニオン型は、エラーセット型単体よりも頻繁に使用される可能性があります[36]

構文(EBNF)
error-union-expr = suffix-expr ( "!" TypeExpr )?
suffix-expr = "async" PrimaryTypeExpr SuffixOp* FnCallArguments
            |       PrimaryTypeExpr ( SuffixOp | FnCallArguments )*
[20]

演算子編集

Zigには、演算子のオーバーロードはありません。 Zigのプログラムに演算子を見たとき、それが次の一覧表に示すもので、それ以外のものでないことが保証されます[37]

演算子一覧表編集

演算子一覧表( Table of Operators )[38]
構文 関連する型 説明 コード例
a + b
a += b
加算
整数の場合、オーバーフローを起こす可能性があります。
オペランドに対してピア型解決を行います。
2 + 5 == 7
a +% b
a +%= b
ラッピング加算
二の補数のラップ動作が保証されています。
オペランドに対してピア型解決を行います。
@as(u32, std.math.maxInt(u32)) +% 1 == 0
a +| b
a +|= b
飽和加算
オペランドに対してピア型解決を行います。
@as(u32, std.math.maxInt(u32)) +| 1 == @as(u32, std.math.maxInt(u32))
a - b
a -= b
減算
整数の場合、オーバーフローを起こす可能性があります。
オペランドに対してピア型解決を行います。
2 - 5 == -3
a -% b
a -%= b
ラッピング減算
二の補数のラップ動作が保証されています。
オペランドに対してピア型解決を行います。
@as(u32, 0) -% 1 == std.math.maxInt(u32)
a -| b
a -|= b
飽和減算
オペランドに対してピア型解決を行います。
@as(u32, 0) -| 1 == 0
-a
符号反転
整数の場合、オーバーフローを起こす可能性があります。
-1 == 0 - 1
-%a
ラッピング符号反転
二の補数のラップ動作が保証されています。
-%@as(i32, std.math.minInt(i32)) == std.math.minInt(i32)
a * b
a *= b
乗算
整数の場合、オーバーフローを起こす可能性があります。
オペランドに対してピア型解決を行います。
2 * 5 == 10
a *% b
a *%= b
ラッピング乗算
二の補数のラップ動作が保証されています。
オペランドに対してピア型解決を行います。
@as(u8, 200) *% 2 == 144
a *| b
a *|= b
* 整数
飽和乗算
オペランドに対してピア型解決を行います。
@as(u8, 200) *| 2 == 255
a / b
a /= b
除算
整数の場合、オーバーフローを起こす可能性があります。
整数の場合、ゼロ除算を起こす可能性があります。
FloatMode.Optimized モードに於いて、浮動小数点数に対してゼロ除算が発生することがあります。
符号付き整数のオペランドは、既知( comptime-known )かつ正でなければなりません。その他の場合は、@divTrunc、@divFloor、または @divExact を代わりに使用してください。
オペランドに対してピア型解決を行います。
10 / 5 == 2
a % b
a %= b
剰余演算
整数の場合、ゼロ除算を起こす可能性があります。
FloatMode.Optimized モードに於いて、浮動小数点数に対してゼロ除算が発生することがあります。
符号付きまたは浮動小数点オペランドは、既知で正の値でなければなりません。それ以外の場合は、代わりに @rem または @mod を使用してください。
オペランドに対してピア型解決を行います。
10 % 3 == 1
a << b
a <<= b
* 整数
左ビットシフト
b は、既知であるか、aのビット数の log2 を持つ型でなければなりません。
1 << 8 == 256
a <<| b
a <<|= b
* 整数
飽和左ビットシフト
@as(u8, 1) <<| 8 == 255
a >> b
a >>= b
* 整数
右ビットシフト
b は、既知であるか、aのビット数の log2 を持つ型でなければなりません。
10 >> 1 == 5
a & b
a &= b
ビット論理積
オペランドに対してピア型解決を行います。
0b011 & 0b101 == 0b001
a | b
a |= b
ビット論理和
オペランドに対してピア型解決を行います。
0b010 | 0b100 == 0b110
a ^ b
a ^= b
ビット排他的論理和
オペランドに対してピア型解決を行います。
0b011 ^ 0b101 == 0b110
~a
ビット反転
~@as(u8, 0b10101111) == 0b01010000
a orelse b
もし anullならば、b("デフォルト値")を返す、そうでなければ,ラップされていない a の値を返す。bnoreturn型の値である可能性があることに注意。
const value: ?u32 = null;
const unwrapped = value orelse 1234;
unwrapped == 1234
a.?
以下に同じ
a orelse unreachable
const value: ?u32 = 5678;
 value.? == 5678
a catch b
a catch |err| b
もし aerrorならば、b("デフォルト値")を返す、そうでなければ,ラップされていない a の値を返す。code>b がnoreturn型の値である可能性があることに注意。 errはエラーであり,式bのスコープ内にある。
const value: anyerror!u32 = error.Broken;
const unwrapped = value catch 1234;
unwrapped == 1234
a and b
論理積
もし afalse ばらば b を評価せずに false を返す。そうでなければ b を返す。
(false and true) == false
a or b
論理和
もし atrue ばらば b を評価せずに true を返す。そうでなければ b を返す。
(false or true) == true
!a
論理否定
!false == true
a == b
ab が等しい場合は true を、そうでない場合は false を返します。オペランドに対してピア型解決を行います。
(1 == 1) == true
a == null
anull の場合は true を、そうでない場合は false を返します。
const value: ?u32 = null;
value == null
a != b
ab が等しい場合は false を、そうでない場合は true を返します。オペランドに対してピア型解決を行います。
(1 != 1) == false
a > b
ab より大きい場合は true を、そうでない場合は false を返します。オペランドに対してピア型解決を行います。
(2 > 1) == true
a >= b
ab より大きいあるいは等しい場合は true を、そうでない場合は false を返します。オペランドに対してピア型解決を行います。
(2 >= 1) == true
a < b
ab より小さい場合は true を、そうでない場合は false を返します。オペランドに対してピア型解決を行います。
(1 < 2) == true
>
a <= b
ab より小さいあるいは等しい場合は true を、そうでない場合は false を返します。オペランドに対してピア型解決を行います。
(1 <= 2) == true
a ++ b
配列の結合
ab が既知の場合のみ使用可能です。
const mem = @import("std").mem;
const array1 = [_]u32{1,2};
const array2 = [_]u32{3,4};
const together = array1 ++ array2;
mem.eql(u32, &together, &[_]u32{1,2,3,4})
a ** b
配列の乗算
ab が既知の場合のみ使用可能です。
const mem = @import("std").mem;
const pattern = "ab" ** 3;
mem.eql(u8, pattern, "ababab")
a.*
ポインターのデリファレンス
const x: u32 = 1234;
const ptr = &x;
ptr.* == 1234
&a
すべて
アドレスを取得
const x: u32 = 1234;
const ptr = &x;
ptr.* == 1234
a || b
エラーセットのマージ
const A = error{One};
const B = error{Two};
(A || B) == error{One, Two}

優先順位編集

 x() x[] x.y x.* x.?
 a!b
 x{}
 !x -x -%x ~x &x ?x
 * / % ** *% *| ||
 + - ++ +% -% +| -|
 << >> <<|
 & ^ | orelse catch
 == != < > <= >=
 and
 or
 = *= *%= *|= /= %= += +%= +|= -= -%= -|= <<= <<|= >>= &= ^= |=

オプショナル型編集

Zigには「オプショナル型」( optional type )と「非オプショナル型」があります。

オプショナル型
値としてnullを受け入れられる。
非オプショナル型
値としてnullを受け入れられない。

ここまでに紹介した変数および定数の型は非オプショナル型です。

オプショナル型の変数および定数は宣言のときに ?型名 と書きます。

var a: i32 = null;  // 非オプショナル型を null で初期化するとエラーになる!
var b: ?i32 = null; // オプショナル型は null で初期化してもエラーにならない

アンラップ編集

オプショナル型の式から基底型の値を参照することをアンラップを呼びます。

ifを使ったアンラップ
const std = @import("std");
const print = std.io.getStdOut().writer().print;

pub fn main() void {
    var s: ?[]const u8 = null;

    if (s) |ss| {
        print("{s}\n", .{ss});
    } else {
        print("it's null\n", .{});
    }

    s = "abc";

    if (s) |ss| {
        print("{s}\n", .{ss});
    } else {
        print("it's null\n", .{});
    }
}
実行結果
it's null
abc

配列編集

構文(EBNF)
array-type-start = "[" expr [ ":" expr ] "]"
[20]

配列と特殊な演算子 ++ と **編集

配列には、特有な演算子が2つあります。

配列のコード例
const print = @import("std").io.getStdOut().writer().print;

pub fn main() !void {
    const ary = [_]i8{ 2, 3, 5, 7 };

    print("ary == {}{{ ", .{@TypeOf(ary)});
    for (ary) |elm| {
        print("{}, ", .{elm});
    }
    print("}}\n", .{});

    print("ary ++ ary == {}{{ ", .{@TypeOf(ary ++ ary)});
    for (ary ++ ary) |elm| {
        print("{}, ", .{elm});
    }
    print("}}\n", .{});

    print("ary ** 3 == {}{{ ", .{@TypeOf(ary ** 3)});
    for (ary ** 3) |elm| {
        print("{}, ", .{elm});
    }
    print("}}\n", .{});
}
実行結果
ary == [4]i8{ 2, 3, 5, 7, } 
ary ++ ary == [8]i8{ 2, 3, 5, 7, 2, 3, 5, 7, } 
ary ** 3 == [12]i8{ 2, 3, 5, 7, 2, 3, 5, 7, 2, 3, 5, 7, }
省略記法
const ary = [_]i8{ 2, 3, 5, 7 };
完全な表記
const ary: [4]i8= [4]i8{ 2, 3, 5, 7 };
ですが、型は型推定で、要素数もリテラルなので _ と書けます。
型名を省略した配列リテラル
const ary: [4]i8= .{ 2, 3, 5, 7 };
宣言で型を明記した場合は、初期値の配列の型は自明なので配列リテラルの型は . で省略できます。
このコードは、タプルを配列の初期値にしています。
配列連結演算子
ary ++ ary
++ は配列と配列を連結した新しい配列を返す演算子です。
配列連結演算子
ary ** 3
** は配列を回数だけ繰返した新しい配列を返す演算子です。
ary ** aryary ++ ary ++ ary と等価です。

多次元配列編集

多次元配列( Multidimensional Arrays )は、ネストした配列で生成します[39]

多次元配列
const print = @import("std").io.getStdOut().writer().print;

pub fn main() !void {
    var matrix : [16][16]i32 = undefined;

    // 全成分を 0 に
    for (matrix) |*col| {
        for (col.*) |*value| {
                value.* = 0;
        }
    }

    print("martix == {}{{\n", .{@TypeOf(matrix)});
    for (matrix) |col| {
        print("  {{ ", .{});
        for (col) |value| {
            print("{}, ", .{value});
        }
        print("}},\n", .{});
    }
    print("}}\n\n", .{});

    // 対角成分を 1 に
    for (matrix) |*col, ci| {
        for (col.*) |*value, ri| {
            if (ci == ri) {
                value.* = 1;
            }
        }
    }

    print("martix == {}{{\n", .{@TypeOf(matrix)});
    for (matrix) |col| {
        print("  {{ ", .{});
        for (col) |value| {
            print("{}, ", .{value});
        }
        print("}},\n", .{});
    }
    print("}}\n", .{});
}
実行結果
martix == [16][16]i32{
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, },
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, },
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, },
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, },
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, },
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, },
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, },
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
}

martix == [16][16]i32{
 { 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, }, 
 { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, }, 
}
多次元配列の宣言
    var matrix : [16][16]i32 = undefined;
undefined で初期化しています。というより初期化していません。
スカラで配列の初期化はできません
    var matrix : [16][16]i32 = 0; // これはエラーにおる
と書きたいところですができないので、二重のforループで初期化しています。
| *変数名 | と * を付けると、 変数名.* で要素を左辺値化できます。


センチネル終端配列編集

センチネル終端配列( Sentinel Terminated Arrays )は、文字列のように特殊な値(センチネル( sentinel;番兵 ))で終端した配列です。 文字列の場合のセンチネルは ’\0’ ですが、構文 [配列長:x]要素型 の x で任意の値をセンチネルにできます[40]

センチネル終端配列
const print = @import("std").io.getStdOut().writer().print;

pub fn main() !void {
    const ary = [_:-1]i32{ 1, 4, 9, 16, 25 };
    print("@TypeOf(ary) ⇒ {}\n", .{@TypeOf(ary)});
    var i: u16 = 0;
    while (i <= ary.len) : (i += 1) {
        print("{} ", .{ary[i]});
    }
}
実行結果
@TypeOf(ary) ⇒ [5:0]i32
1 4 9 16 25 -1

ベクトル編集

ベクトルは、bool整数浮動小数点数ポインターのグループで、可能であればSIMD命令を使って並列に操作されます。ベクトル型は、組込み関数 @Vector で作成します[41]

ベクトルは、基本型と同じ組み込み演算子をサポートしています。これらの演算は要素ごとに行われ、入力ベクトルと同じ長さのベクトルを返します。これには以下が含まれます。

算術演算
+, -, /, *, @divFloor, @sqrt, @ceil, @log, など
ビット演算子
>>, <<, &, |, ~, など
比較演算子
<, >, ==, など

スカラー(個々の数値)とベクトルが混在している場合に数学演算子を使用することは禁止されています。Zigでは、スカラーからベクトルへの変換を容易にするために組込み関数@splatが用意されており、ベクトルからスカラーへの変換には組込み関数@reduceと配列インデックスの構文がサポートされています。ベクトルは、長さが既知の固定長の配列との間の代入もサポートしています。

Zigは,組込み関数@shuffleと組込み関数@selectを提供し,ベクトル内やベクトル間の要素の並べ替えを行います.

ターゲットマシンのネイティブ SIMD サイズより短いベクトルに対する操作は、通常は単一の SIMD 命令にコンパイルされます。ある演算がターゲット・アーキテクチャで SIMD をサポートしていない場合、コンパイラはデフォルトで各ベクトル要素に対して一度に 1 つずつ演算します。Zig は、232-1 までの既知のベクトル長をサポートしていますが、2 の累乗(2-64)が最も一般的です。ただし、現在の Zig では、長すぎるベクトル長 (例えば 220) はコンパイラがクラッシュする可能性があります。

ベクトル演算
const print = @import("std").io.getStdOut().writer().print;

pub fn main() !void {
    const a = @Vector(4, i32){ 1, 2, 3, 4 };
    const b = @Vector(4, i32){ 5, 6, 7, 8 };

    print("  {}\n+ {}\n= {}\n\n", .{ a, b, a + b });
    print("  {}\n- {}\n= {}\n\n", .{ a, b, a - b });
    print("  {}\n* {}\n= {}\n\n", .{ a, b, a * b });
    print("  {}\n/ {}\n= {}\n\n", .{ a, b, a / b });
    print("  {}\n% {}\n= {}\n\n", .{ a, b, a % b });
}
実行結果
  { 1, 2, 3, 4 } 
+ { 5, 6, 7, 8 } 
= { 6, 8, 10, 12 }
  
  { 1, 2, 3, 4 }
- { 5, 6, 7, 8 } 
= { -4, -4, -4, -4 }

  { 1, 2, 3, 4 } 
* { 5, 6, 7, 8 } 
= { 5, 12, 21, 32 }

  { 1, 2, 3, 4 } 
/ { 5, 6, 7, 8 } 
= { 0, 0, 0, 0 } 

  { 1, 2, 3, 4 } 
% { 5, 6, 7, 8 } 
= { 1, 2, 3, 4 }

[TODO:配列との相互変換]

ポインター編集

Zigには、単一項目と多項目の2種類のポインターがあります[42]

  • *T - 正確に1つの項目への単一項目ポインター。
    • deref構文をサポート: ptr.*
  • [*]T - 未知数のアイテムへの多項目ポインター。
    • インデックス構文をサポート: ptr[i]
    • スライス構文をサポート: ptr[start..end]
    • ポインター演算をサポート: ptr + x, ptr - x
    • T は既知のサイズでなければならず、anyopaqueや他の opaque型 にはできません。

これらの型は、配列スライスと密接に関係しています。

  • *[N]T - N 個のアイテムへのポインター、配列への単項目ポインターと同じです。
    • インデックス構文に対応: array_ptr[i]
    • スライス構文に対応: array_ptr[start..end]
    • lenプロパティをサポート: array_ptr.len
  • []T - スライス (ファットポインター。[*]T型のポインターと長さを含みます)。
    • インデックス構文に対応: slice[i]
    • スライス構文に対応: slice[start..end]
    • lenプロパティをサポート: slice.len

単一項目ポインター編集

単項目ポインターを得るには、&xを使用します。

多項目ポインター編集

[TODO]

volatile編集

ロードとストアは、副作用がないことが前提です。MMIO (Memory Mapped Input/Output) のように、ロードやストアが副作用を持つべき場合は volatile を使用します[43]

アライメント編集

それぞれの型にはアライメント( Alignment )があり、その型の値がメモリからロードされたり、メモリにストアされたりするとき、メモリアドレスがこの数で均等に割り切れるようなバイト数になっています。この値は組込み関数 @alignOf を使って知ることができます[44]

アラインメントはCPUアーキテクチャに依存しますが、常に2のべき乗であり、1 << 29 より小さい値です。

Zigでは、ポインター型はアライメント値を持っています。この値が基礎となる型のアライメントと等しい場合、その型は省略することができます。

align編集

align は、ポインターのアライメントを指定するために使用します。また、変数や関数の宣言の後に使用して、その変数や関数へのポインターのアライメントを指定することができます。

allowzero編集

allowzeroポインター属性は、ポインターのアドレスがゼロであることを許可します。これは、アドレスゼロがマッピング可能な独立型OSターゲットでのみ必要とされます。nullポインターを表現したい場合は、代わりにオプショナルポインターを使用します。allowzeroを持つオプショナルポインターは、ポインターと同じサイズではありません[45]

const編集

constポインター属性は、(ポインターではなく)ポインターが参照する値が変更できないことを示します。

センチネル終端ポインター編集

センチネル終端ポインター( Sentinel Terminated Pointers )。 構文 [*:x]T は、センチネル値によって長さが決定されるポインターを記述します。これにより、バッファオーバーフローやオーバーリードから保護されます[46]

スライス編集

スライス( Slices )はポインターと長さです。配列とスライスの違いは、配列の長さが型の一部でコンパイル時にわかるのに対して、スライスの長さは実行時にわかることです。どちらも len プロパティでアクセスすることができます[47]

スライスを使ったコード例
const print = @import("std").io.getStdOut().writer().print;

pub fn main() !void {
    var array = [_]i32{ 2, 3, 5, 7, 11, 13, 17 };
    var q: usize = 1;
    const slice = array[q .. array.len -1];

    print("@TypeOf(slice) ⇒ {}\n", .{@TypeOf(slice)});
    for (slice) |x| {
        print("{} ", .{x});
    }
}
実行結果
@TypeOf(slice) ⇒ []i32 
3 5 7 11 13

センチネル終端スライス編集

センチネル終端スライス( Sentinel-Terminated Slices )。 構文[:x]Tは、実行時に既知の長さを持ち、また長さでインデックスされた要素で センチネル値を保証するスライスです。この型は、それ以前にセンチネル要素がないことを保証するものではありません。センチネル終端スライスはlenインデックスへのエレメントアクセスを可能にします[48]

スライスを使ったコード例
const print = @import("std").io.getStdOut().writer().print;

pub fn main() !void {
    const slice: [:0]const u8 = "hello";

    print("@TypeOf(slice) ⇒ {}\n", .{@TypeOf(slice)});
    for (slice) |ch| {
        print("{c} ", .{ch});
    }
}
実行結果
@TypeOf(slice) ⇒ [:0]const u8 
h e l l o

コンテナー編集

Zig は、structenumunionopaque の4つの組込みコンテナー( container )を持ちます。

[TODO:std.containerについて]

構文(EBNF)
container-members = container-declarations ( container-field "," )* (container-field | container-declarations)
container-declarations = TestDecl container-declarations   
                      | TopLevelComptime container-declarations
                      | [ doc_comment ] [ "pub" ] TopLevelDecl container-declarations
                      | 
container-field = [ doc_comment ] [ "comptime" ] IDENTIFIER [ ":" ( "anytype" | TypeExpr)  [ ByteAlign ] ] [ "=" expr ]

container-decl-auto = container-decl-type "{" [ container_doc_comment ] container-members "}"
container-decl-type = "struct" 
                  | "opaque" 
                  | "enum" [ "(" expr ")" ]
                  | "union" [ "(" ( "enum" [ "(" expr ")" ] ) | expr  ")"
コンテナー関連の構文を抜粋[20]

struct編集

struct(構造あるいは構造型[49])は、フィールドと呼ばれる名前の付いた要素の集まりで、それぞれのフィールドは名前と型を持っています。

struct の定義
const print = @import("std").io.getStdOut().writer().print;

const Complex = struct {
    real: f64,
    imag: f64,
};

pub fn main() !void {
    print("@TypeOf(Complex) ⇒ {}\n", .{@TypeOf(Complex)});
}
実行結果
@TypeOf(Complex) ⇒ type
3-6 行目が struct の宣言で、変数に保存しています。
struct で宣言した値の型は type です。
ところで Zigはフィールドの順番とサイズを保証しません。しかし、フィールドはABIアラインされていることが保証されています[50]
もし、順番とサイズを保証したい場合キーワード packed を前置します。
順番とサイズを保証したい場合
const Complex = packed struct {
    real: f64,
    imag: f64,
};
インスタンスの生成
const print = @import("std").io.getStdOut().writer().print;

const Complex = struct {
    real: f64,
    imag: f64,
};

pub fn main() !void {
    const cplx = Complex{
        .real = 1.2,
        .imag = 4.1,
    };
    print("{}\n", .{ cplx });
}
実行結果
Complex{ .real = 1.2e+00, .imag = 4.1e+00 }
メンバー名の前に . が付くのが独特です。
メンバーは常に pub です。
private や protected や friend はありません。
メソッド編集

struct はメソッド( Methods )を持つことができます。 メソッドは特別なものではなく、名前空間を持つだけです。 ドットシンタックス(インスタンス名.メソッド名)で呼び出すことができる関数です。

メソッドの例
const print = @import("std").io.getStdOut().writer().print;
const sqrt = @import("std").math.sqrt;

const Complex = struct {
    real: f64,
    imag: f64,
    pub fn init(real: f64, imag: f64) Complex {
        return Complex{
            .real = real,
            .imag = imag,
        };
    }
    pub fn abs(self: Complex) f64 {
        return sqrt(self.real * self.real + self.imag * self.imag);
    }
};

pub fn main() !void {
    const cplx = Complex.init(3.3, 4.4);
    print("cplx = {}\n", .{cplx});
    print("cplx.abs() = {}\n", .{cplx.abs()});
    print("Complex.abs(cplx) = {}\n", .{Complex.abs(cplx)});
}
実行結果
cplx = Complex{ .real = 3.3e+00, .imag = 4.4e+00 } 
cplx.abs() = 5.5e+00 
Complex.abs(cplx) = 5.5e+00
インスタンスを生成するメソッド init() と絶対値を返すメソッド abs() を定義しました。
インスタンスを生成するメソッドに init と名付けるのも、フィールドにアクセスするメソッドの第一引数を self と名付けるのも言語仕様ではなく慣習ですが、逸脱する積極的な理由はありません。

[TODO:組込み関数@This]

匿名structリテラル編集

Zigでは、structリテラルの型は識別子と結びついている必要はありません。結果が強制される場合、structリテラルはコピーなしで結果の場所を直接インスタンス化します。 この様に、識別子と結びついていないstructリテラルを、匿名structリテラル( Anonymous Struct Literals )あるいはタプル( Tuple )と呼びます[51]

enum編集

Zigでは、重複しない識別子の集合を表現する型 enum が用意されています[52]

enum の定義
const print = @import("std").io.getStdOut().writer().print;

const Colour = enum {
    red,
    green,
    blue,
};

const JISC5062 = enum(u4) {
    black = 0,
    brown,
    red,
    orange,
    yellow,
    green,
    blue,
    violet,
    gray,
    white,

    const Self = @This();
    const len = @typeInfo(Self).Enum.fields.len;
    pub fn allCases() [Self.len]Self{
       var result : [Self.len]Self = undefined;
       var i : u4 = 0;
       while (i < Self.len) : (i += 1) {
           result[i] = @intToEnum(Self, i);
       }
       return result;
    }
};

pub fn main() !void {
    print("@TypeOf(Colour) ⇒ {}\n", .{@TypeOf(Colour)});
    const c = Colour.green;
    print("c ⇒ {}\n", .{c});
    print("JISC5062.allCases() ⇒ {s}\n", .{JISC5062.allCases()});
    for (JISC5062.allCases()) |e| {
        print("{s} ⇒ {}\n", .{ @tagName(e), @enumToInt(e) });
    }
}
実行結果
@TypeOf(Colour) ⇒ type 
c ⇒ Colour.green 
JISC5062.allCases() ⇒ { JISC5062.black, JISC5062.brown, JISC5062.red, JISC5062.orange, JISC5062.yellow, JISC5062.green, JISC5062.blue, JISC5062.violet, JISC5062.gray, JISC5062.white } 
black ⇒ 0 
brown ⇒ 1 
red ⇒ 2 
orange ⇒ 3 
yellow ⇒ 4 
green ⇒ 5 
blue ⇒ 6 
violet ⇒ 7 
gray ⇒ 8 
white ⇒ 9
3-7,9-31行目が enum の宣言で、それぞれ変数に保存しています。
enum で宣言した値の型は type です。
enum は、struct と同じくメンバーとは別に、型に属する変数やメソッドを持つことが出来ます。
JISC5062.allCases() は、JISC5062のメンバー全てを含む配列を返しています。
const Self = @This();は、コンテナー定義でコンテナーの識別子を書く手間をなくし、コピーアンドペーストを容易にします。
red, green と blue が Colour と JISC5062 で重複していますが、コンテナーは名前空間として機能するので問題になりません。

union編集

union は、ある値が取り得る型の集合をフィールドのリストとして定義します[53]。 一度にアクティブにできるフィールドは1つだけです。union のメモリ内表現は保証されません。 union はメモリの再解釈に使用できません。その場合は、@ptrCast を使用するか、メモリ内レイアウトが保証されている extern union または packed union を使用します。 非アクティブフィールドへのアクセスは安全が確認された未定義動作です。

非アクティブフィールドを参照するとコンパイルエラーになります
const std = @import("std");
const print = std.io.getStdOut().writer().print;

const SimpleUnion = union {
    char: u8,
    int: i64,
    float: f64,
};

pub fn main() void {
    var su = SimpleUnion{ .char = 'C' };
    print("su.int = {}\n", .{su.int});
}
コンパイル結果
panic: access of inactive union field
アクティブフィールドであれば参照できます
const std = @import("std");
const print = std.io.getStdOut().writer().print;

const SimpleUnion = union {
    char: u8,
    int: i64,
    float: f64,
};

pub fn main() void {
    var su = SimpleUnion{ .char = 'C' };
    print("su.char = {c}\n", .{su.char});
    su = SimpleUnion{ .int = 42 };
    print("su.int = {}\n", .{su.int});
    su = SimpleUnion{ .float = 2.71828_18284_59045_23536_02874_71352 };
    print("su.float = {}\n", .{su.float});
}
実行結果
su.char = C
su.int = 42 
su.float = 2.718281828459045e+00
タグ付きunion編集

union はenumタグタイプを伴って宣言することができます。これにより unionは、タグ付きunion( Tagged union )になり、switch式で使用することができるようになります。タグ付きunionは、そのタグ型に強制されます[54]

タグ付きunion
const std = @import("std");
const print = std.io.getStdOut().writer().print;

const Tag = enum {
    char,
    int,
    float,
};

const TaggedUnion = union(Tag) {
    char: u8,
    int: i64,
    float: f64,
};

pub fn main() void {
    var tu = TaggedUnion{ .char = 'C' };
    print("@as(Tag, tu) ⇒ {}\n", .{@as(Tag, tu)});
    switch (tu) {
        Tag.char => |ch| print("ch = {c}\n", .{ch}),
        Tag.int => |i| print("i = {}\n", .{i}),
        Tag.float => |f| print("f = {}\n", .{f}),
    }
}
実行結果
@as(Tag, tu) ⇒ Tag.char 
ch = C
タグの enum と、それを使うタグ付きunionのメンバー集合は一致していないとエラーになります。
タグ付きunionを式とするswitch式では、バターンでタグのメンバーを網羅している必要があります(網羅性の検証が行えます。ただし _ や else をパターン使うと台無し)。

構文木を考えてみましょう。Cで実装するとノードの種別と種別ごとのペイロードの共用体になります。Zigではこれを一般化してタグ付きunion1つで実装することが出来ます。 タグ付きunionを使うと網羅性の保証もでき、多くの特性をメソッドとして記述できます。たとえばキーワードや演算子を追加した場合、対応するswitchのパターンがないとエラーになりコンパイル時に事前に変更必要箇所を確認できます。

switch式でタグ付きunionの値の変更編集

switch式でタグ付きunionのペイロードを変更するには、変数名の前に*を置き、ポインターにします

switch式でタグ付きunionの値の変更
const std = @import("std");
const print = std.io.getStdOut().writer().print;

const Tag = enum {
    char,
    int,
    float,
};

const TaggedUnion = union(Tag) {
    char: u8,
    int: i64,
    float: f64,
};

pub fn main() void {
    var tu = TaggedUnion{ .int = 42 };
    print("@as(Tag, tu) ⇒ {}\n", .{@as(Tag, tu)});
    switch (tu) {
        Tag.char => |*ch| ch.* -= 1,
        Tag.int => |*i| i.* += 10,
        Tag.float => |*f| f.* /= 1.2,
    }
    print("tu.int ⇒ {}\n", .{tu.int});
}
実行結果
@as(Tag, tu) ⇒ Tag.int 
tu.int ⇒ 52
unionのメソッド編集

union も他のコンテナーと同様にメソッドを持つことが出来ます。

[TODO:コード例]

extern union編集

[TODO:コード例] [55]

packed union編集

[TODO:コード例] [56]

匿名unionリテラル編集

[TODO:コード例]

Anonymous Union Literals [57]

opaque編集

「TODO:訳語未定:キーワードはそのままにすべき?]

ブロック編集

ブロックは、変数宣言の範囲を限定するために使用されます。

構文(EBNF)
block = "{" statement* "}"

statement = "comptime"? var-decl
          | "comptime" block-expr-statement
          | "nosuspend" block-expr-statement
          | "suspend" block-expr-statement
          | "defer" block-expr-statement
          | "errdefer" pay-load? block-expr-statement
          | if-statement
          | labeled-statement
          | switch-expr 
          | AssignExpr ";"
[20]

ブロックの値編集

ブロックは式です。ラベルを付けると、break はブロックから値を返すために使うことができます。

const print = @import("std").io.getStdOut().writer().print;

pub fn main() !void {
    var y: i32 = 123;
    const x = blk: {
        y += 1;
        break :blk y + 2;
    }; 
    try print("x = {}, y = {}\n", .{x, y});
}
実行結果
x = 126, y = 124
ラベル blk は、任意の識別子に置換えられますが、慣習として blk がよく用いられます。

シャドーイング編集

識別子は、同じ名前を使用して他の識別子を "隠す"ことは決して許されません。 コンパイラーは、外部スコープで既に使われている識別子を、ブロック内で使うとエラーにします。

このため、Zigのコードを読むときには、その識別子が定義されたスコープ内では常に同じ意味であることを確認することができます。ただし、スコープが分かれている場合(入れ子関係にない場合)には同じ名前を使用することができます。

defer編集

defer は、現在のスコープの末尾で実行する式またはブロックを登録します。

const std = @import("std");
const print = std.io.getStdOut().writer().print;

fn basic_example() !usize {
    var x: usize = 0;

    {
        defer x = 123;
        x = 0;
        print("@small block: x = {}\n", .{x});
    }
    print("@function block: x = {}\n", .{x});

    x = 5;
    return x;
}

fn multiple_example() void {
    print("multiple_example(): ", .{});

    defer {
        print("1 ", .{});
    }
    defer {
        print("2 ", .{});
    }
    if (false) {
        // defer 自身が一度も実行されない場合は、実行されません。
        defer {
            print("3 ", .{});
        }
    }
}

pub fn main() !void {
    print("basic_example()  = {}\n", .{basic_example()});
    multiple_example();
}
実行結果
@small block: x = 0 
@function block: x = 123 
basic_example()  = 5 
multiple_example(): 2 1

{{See also|[[#errdefer|errdefer}}

キャスト編集

[TODO:Zig は強い型付け(); 型強制 (Type coercion) について]

型キャスト( type cast )は、ある型の値を別の型に変換するものです。Zigには、完全に安全で曖昧さのないことが分かっている変換のための型強制( Type Coercion )と、偶然に起こって欲しくはない変換のための明示的キャスト( Explicit Casts )があります。また、複数のオペランド型から結果の型を決めなければならない場合のために、ピア型解決( Peer Type Resolution )と呼ばれる第3の型変換があります[58]

型強制編集

型強制( Type Coercion )

明示的キャスト編集

明示的キャスト( Explicit Casts )

ピア型解決編集

ピア型解決( Peer Type Resolution )

アセンブリ言語との連携編集

[TODO:所謂インラインアセンラ]

atomic編集

非同期関数編集

Zigでは、キーワード async を伴って関数またはメソッドを呼び出すと、その関数またはメソッドの処理を休止し再開することができます。

async.zig
const std = @import("std");

var frame: anyframe = undefined;

pub fn main() void {
    println("begin main");
    _ = async func();
    println("resume func");
    resume frame;
    println("end main");
}

fn func() void {
    println("begin func");
    frame = @frame();
    suspend {}
    println("end func");
}

fn println(s: []const u8) void {
    std.io.getStdOut().writer().print("{s}\n",.{s});
}
実行結果
begin main
begin func
resume func
end func
end main

unreachable編集

Debug と ReleaseSafe モード、および zig test を使用する場合、unreachable は到達不能なコードに到達したメッセージとともに panic への呼び出しを出します。

ReleaseFast モードでは、オプティマイザーは到達不能なコードは決してヒットしないという仮定を使用して最適化を実行します。しかし、ReleaseFastモードでもzigテストはunreachableをpanicへの呼出しとして出力します。

組込み関数編集

組込み関数( Builtin Functions )はコンパイラーが提供するもので、@ が先頭に付きます。パラメーターのキーワード comptime は、そのパラメーターがコンパイル時に既知でなければならないことを意味します[59]

組込み関数一覧
関数プロトタイプ 種別 説明
@addWithOverflow(comptime T: type, a: T, b: T, result: *T) bool
数値演算 result.* = a + b を実行します。オーバーフローまたはアンダーフローが発生した場合、resultにオーバーフローしたビットを格納し、trueを返します。オーバーフローまたはアンダーフローが発生しない場合、falseを返します[60]
@alignCast(comptime alignment: u29, ptr: anytype) anytype
アライメント ptr は *T, fn(), ?*T, ?fn(), または []T のいずれかです。これは ptr と同じ型を返しますが、アライメントが新しい値に調整されています。

ポインターのアラインメントが約束通りかどうかを確認するために、生成されたコードにポインターのアラインメント安全検査が追加されています[61]

@alignOf(comptime T: type) comptime_int
アライメント この関数は、現在のターゲットがCのABIに適合するために、この型がアライメントされるべきバイト数を返します。ポインターの子供の型がこのアライメントを持っている場合、アライメントを省略することができます[62]
@as(comptime T: type, expression) T
キャスト 型強制を行います。このキャストは、変換が曖昧でなく安全である場合に許可され、可能な限り、型間の変換に好ましい方法とされています[63]
@asyncCall(frame_buffer: []align(@alignOf(@Frame(anyAsyncFunction))) u8, result_ptr, function_ptr, args: anytype) anyframe->T
非同期処理 関数ポインターに対して非同期呼び出しを実行します(非同期関数であってもなくてもかまいません)。

提供される frame_buffer は、関数のフレーム全体を収めるのに十分な大きさでなければなりません。このサイズは @frameSize で決定することができます。小さすぎるバッファを提供すると、安全が確認された未定義の動作が発生します。 result_ptr はオプションです(null を指定することもできます)。提供された場合、関数コールはその結果を結果ポインターに直接書き込み、await が完了した後にそれを読むことができるようになります。await に提供された結果は、result_ptr で示された場所にコピーされます。 [64]

@atomicLoad(comptime T: type, ptr: *const T, comptime ordering: builtin.AtomicOrder) T
不可分操作 ポインターをアトミックにデリファレンスしてその値を返します。

T は、ポインターbool整数浮動小数点数あるいは enum でなければなりません[65]

@atomicRmw(comptime T: type, ptr: *T, comptime op: builtin.AtomicRmwOp, operand: T, comptime ordering: builtin.AtomicOrder) T
不可分操作 メモリをアトミックに変更した後、以前の値を返します[66]

T は、ポインターbool整数浮動小数点数あるいは enum でなければなりません。

サポートされている操作
  • .Xchg - オペランドを変更せずに保存します。enum、整数および浮動小数点数をサポートします。
  • .Add - 整数に対して、2 の補数ラップアラウンド加算を行います。浮動小数点数もサポートしています。
  • .Sub - 整数に対して、2 の補数のラップアラウンド減算を行います。浮動小数点数もサポートしています。
  • .And - ビット単位の論理積
  • .Nand - ビット単位の論理積の反転
  • .Or - ビット単位の論理和
  • .Xor - ビット単位の排他的論理和
  • .Max - オペランドが大きい場合に、オペランドを格納します。整数および浮動小数点数をサポートします。
  • .Min - 小さければ、オペランドを格納します。整数と浮動小数点数をサポートします。
@atomicStore(comptime T: type, ptr: *T, value: T, comptime ordering: builtin.AtomicOrder) void
不可分操作 値をアトミックに保存します。

T は、ポインターbool整数浮動小数点数あるいは enum でなければなりません[67]

@bitCast(comptime DestType: type, value: anytype) DestType
キャスト ある型の値を別の型に変換します[68]
  • sizeOf(@TypeOf(value)) == @sizeOf(DestType) の保証
  • typeInfo(DestType) != .Pointerであることの保証

これが必要な場合は@ptrCast@intToPtrを使ってください。

例えばこんなことに使えます。

  • f32をu32ビットに変換する
  • i32をu32に変換し、2補数を保持する。

コンパイル時に値が既知であれば、コンパイル時に動作します。つまり、専用のキャスト用組込み関数(enum、ポインター、エラー集合型)を持つ型からの制限に加えて、struct、エラーユニオン、スライス、オプショナル型、その他メモリレイアウトが明確に定義されていない型も、この操作に使用できないことを意味しています。

@bitOffsetOf(comptime T: type, comptime field_name: []const u8) comptime_int
オフセット フィールドのビットオフセットを、それを含む struct からの相対値で返します。

パックされていない struct の場合、これは常に 8 で割り切れる値になります。packed struct の場合、非バイトアラインのフィールドはバイトオフセットを共有しますが、ビットオフセットはそれぞれ異なります[69]

@boolToInt(value: bool) u1
キャスト true を @as(u1, 1) に、false を @as(u1, 0) に変換します。

コンパイル時に値が分かっている場合、戻り値の型は u1 ではなく comptime_int になります[70]

@bitSizeOf(comptime T: type) comptime_int
特性 型がパックされたstruct/unionのフィールドであった場合に、Tをメモリに格納するために必要なビット数を返します。この結果は、ターゲット固有のコンパイル時定数です。

この関数は、実行時にサイズを測定する。comptime_intやtypeのような実行時に許可されない型については、結果は0を返します[71]

@breakpoint()
デバッグ プラットフォーム固有のデバッグトラップ命令を挿入し、デバッガがそこでブレークするようにします。

この関数は、関数スコープ内でのみ有効です[72]

@mulAdd(comptime T: type, a: T, b: T, c: T) T
数値演算 積和演算( Fused multiply add )は、(a * b) + c に似ていますが、丸めが一度だけしか行われないためより正確です。

浮動小数点数と浮動小数点数のベクトルをサポートしています[73]

@byteSwap(operand: anytype) T
エンディアン操作 @TypeOf(operand)は、整数型またはビット数が8で均等に割り切れる整数型ベクトル型でなければなりません。

operand は、整数またはベクトルでなければなりません。 整数のバイトオーダーを入れ替えます。これは、ビッグエンディアン整数をリトルエンディアン整数に変換し、リトルエンディアン整数をビッグエンディアン整数に変換します。 エンディアンを考慮したメモリレイアウトのためには、整数の型は @sizeOf bytes で報告されるバイト数に関係する必要があることに注意してください。これはu24で実証されている。つまり、メモリに格納されたu24は4バイトかかり、この4バイトがリトルエンディアンとビッグエンディアンのシステムでスワップされるものであることを意味します。一方、Tがu24と指定されている場合は、3バイトしか反転されません[74]

@bitReverse(integer: anytype) T
ビット操作 TypeOf(anytype) は、任意の整数型または整数ベクトル型を受け付けます[75]

整数値のビットパターンを反転します(符号ビットがある場合はそれも含めて)。

例えば、0b10110110 (u8 = 182, i8 = -74) は、0b01101101 (u8 = 109, i8 = 109) になります。

@offsetOf(comptime T: type, comptime field_name: []const u8) comptime_int
オフセット フィールドのバイトオフセットを、それを含む struct の先頭からの相対値で返します[76]
@call(options: std.builtin.CallOptions, function: anytype, args: anytype) anytype
関数呼出し 括弧で囲まれた式を呼び出すのと同じように、関数を呼び出します[77]

@call は、通常の関数呼出し構文よりも柔軟性があります。

@cDefine(comptime name: []u8, value)
C言語API この関数は @cImport の内部でのみ使用可能です。これは、#define $name $value を @cImport の一時バッファに追加します[78]
@cDefine("_GNU_SOURCE", {})
#define _GNU_SOURCE
に相当します。
@cImport(expression) type
C言語API この関数は、Cコードを解析し、関数、型、変数、互換マクロ定義を新しい空の struct 型にインポートし、その型を返します[79]

式はコンパイル時に解釈されます。組込み関数の @cInclude, @cDefine, @cUndef はこの式の中で動作し、C コードとしてパースされる一時バッファに追加されます。

通常、アプリケーション全体で @cImport は 1 つだけにしてください。コンパイラーが clang を複数回呼び出す手間を省き、インライン関数が重複するのを防ぐことができるからです。

複数の @cImport 式を持つ理由としては、以下のようなものが考えられます。

  • シンボルの衝突を避けるため,例えば foo.h と bar.h の両方が #define CONNECTION_COUNT の場合
  • プリプロセッサの定義が異なるC言語のコードを解析する場合
@cInclude(comptime path: []u8)
C言語API この関数は @cImport の内部でのみ使用可能です。これは c_import の一時的なバッファに #include <$path></path> を追加します[80]


メモリ管理編集

キーワード一覧編集

align
ポインターのアライメントを指定するために使用します。また、変数や関数の宣言の後に使用して、その変数や関数へのポインターのアライメントを指定することができます。
allowzero
ポインターの属性 allowzero は、ポインターのアドレスが 0 であることを許可します
and
論理積
anyframe
関数フレームへのポインターを保持する変数の型として使用することができます。
anytype
関数のパラメータは、型の代わりにanytypeで宣言することができます。型は関数が呼び出された場所で推測されます
asm
インラインアセンブリ式を開始します。これにより、コンパイル時に生成される機械語を直接制御することができます。
async
関数呼び出しの前に使用することで、関数がサスペンドされたときにそのフレームへのポインターを取得することができます。
await
await の後に提供されるフレームが完了するまで、現在の関数を中断するために使用することができます。await は、ターゲット関数のフレームから返される値を呼び出し側にコピーします。
break
ブロックラベルと一緒に使うことで、ブロックから値を返すことができます。また、ループが自然に終了する前に終了させることもできます。
callconv
関数の呼出し規則を変更します。
catch
前の式がエラーと評価された場合に、その式を評価するために使用することができます。catchの後の式は、オプションでエラー値をキャプチャすることができます。[TODO:クリーンアップ]
comptime
コンパイル時に変数や関数パラメータが既知であることを示すために、宣言の前に comptime を使用することができます。また、コンパイル時に式の実行を保証するために使用することもできます。
const
変更できない変数を宣言します。また、ポインターの属性として使用すると、ポインターが参照する値を変更できないことを示す。
continue
ループの中で使うと、ループの最初にジャンプして戻ることができます。
defer
制御フローが現在のブロックから離れるときに式を実行します。
else
ifswitchwhileforの代替ブランチ( alternate branch )を提供するために使用できます。
  • if の後で使用した場合、elseブランチ はテスト値が false、null、またはerrorを返した場合に実行されます。
  • switch式の中で使用した場合、elseブランチはテスト値が他のケースと一致しない場合に実行されます。
  • ループの後で使用した場合、else分岐はループがブレークせずに終了した場合に実行されます。
  • if, switch, while, forも参照してください。
enum
enum型を定義します。
errdefer
関数がエラーを返した場合、制御フローが現在のブロックを離れるときに式を実行します。
error
error型を定義します。
export
生成されたオブジェクトファイルにおいて、関数や変数を外部から見えるようにします。エクスポートされた関数は、デフォルトでC言語の呼出し規則( calling convention )に従います。
extern
静的にリンクする場合はリンク時に、動的にリンクする場合は実行時に解決される関数や変数を宣言するために使用することができます。
fn
関数を宣言します。
for
スライス配列タプルの要素に対して反復処理を行うために使用します。
if
論理式オプショナル値エラーユニオンをテストすることができます。オプショナル値やエラーユニオンの場合、if はラップされていない値をキャプチャすることができます。
inline
コンパイル時にループ式が展開されるようにラベル付けするために使用されます。また、関数のすべての呼出し箇所で強制的にインライン化することもできます。
noalias
TODO add documentation for noalias
nosuspend
ブロック、文、式の前で使用することができ、サスペンドポイントに到達しないスコープをマークすることができます。
特に、nosuspend スコープの内部では
  • suspend キーワードを使用すると、コンパイルエラーになります。
  • まだ完了していない関数フレームで await を使用すると、安全が確認された未定義の動作になる。
  • 非同期関数を呼び出すと、await を含む await async some_async_fn() と等価であるため、安全が確認された未定義の動作になることがある。
nosuspendスコープ内のコードは、それを囲む関数を非同期関数にすることはありません。
opaque
サイズとアライメントが未知の(ただしゼロではない)新しい型を宣言します。
or
論理和
orelse
前の式が null と評価される場合に、その式を評価するために使用することができます。
packed
struct 定義の前にキーワード packed キーワードを指定すると、その構造体のメモリ内レイアウトが保証された packed レイアウトに変更されます。
pub
トップレベル宣言の前にある pub は、その宣言が宣言されているファイルとは異なるファイルから参照できるようにます。
resume
関数が中断された時点から、その関数のフレームを継続して実行します。
return
値を伴って関数を終了させます。
linksection
TODO add documentation for linksection
struct
struct を宣言します。
suspend
制御フローを関数の呼び出し側または再呼出し側に戻します。suspendは、関数内のブロックの前にも使用でき、制御フローが呼び出し側に戻る前に関数がそのフレームにアクセスできるようにします。
switch
共通の型の値をテストするために使用することができます。switchケースは、タグ付けされたユニオンのフィールド値をキャプチャすることができます。
test
動作が期待に沿うことを確認するために使用されるコードのトップレベルブロックを示すために使用します。
threadlocal
変数をスレッドローカルとして指定するために使用します。
try
エラーユニオン式を評価する。もしそれがエラーであれば、同じエラーで現在の関数から戻る。そうでない場合は、式はラップされていない値になります。
union
<coed>unionを定義します。
unreachable
制御フローが特定の場所で発生することがないことを保証するために使用することができます。ビルドモードによっては、unreachableはパニックを発生させるかもしれません。
usingnamespace
structunion、または enum でなければならないオペランドのすべての公開宣言を現在のスコープにインポートするトップレベルの宣言を行います。
var
変更可能な変数を宣言します。
volatile
ポインターのロードやストアに副作用があることを示すために使用されます。また、インラインアセンブリ式を修正して、副作用があることを示すこともできます。
while
booleanoptionalerrorの各ユニオン式を繰返しテストし、それぞれfalsenullerrorと評価された時点でループを停止するために使用されます。

チートシート編集

[TODO:文法と型と頻用する標準ライブラリの関数と型のアンチョコ]

リファレンス篇編集

脚註編集

  1. ^ Home ⚡ Zig Programming Language”. ziglang.org. 2022年7月17日閲覧。
  2. ^ Introduction to the Zig Programming Language”. andrewkelley.me. 2022年7月17日閲覧。
  3. ^ Releases · ziglang/zig · GitHub”. github.com. 2022年9月16日閲覧。
  4. ^ Zig Documentation(master@2022-07-17)”. ziglang.org. 2022年7月17日閲覧。
  5. ^ Zig Documentation(0.9.1)”. ziglang.org. 2022年7月17日閲覧。
  6. ^ Zig Documentation(0.8.1)”. ziglang.org. 2022年7月17日閲覧。
  7. ^ 0.8.0 Release Notes”. ziglang.org. 2022年7月17日閲覧。 “Disable the special casing of {} for u8 slices/arrays. Unless {s} is specified the contents won't be treated as a string.”
  8. ^ Zig Documentation(0.7.1)”. ziglang.org. 2022年7月17日閲覧。
  9. ^ Zig Documentation(0.6.0)”. ziglang.org. 2022年7月17日閲覧。
  10. ^ Zig Documentation(0.4.0)”. ziglang.org. 2022年7月17日閲覧。
  11. ^ Zig Documentation(0.5.0)”. ziglang.org. 2022年7月17日閲覧。
  12. ^ Zig Documentation(0.3.0)”. ziglang.org. 2022年7月17日閲覧。
  13. ^ Zig Documentation(0.2.0)”. ziglang.org. 2022年7月17日閲覧。
  14. ^ Zig Documentation”. ziglang.org. 2022年7月17日閲覧。
  15. ^ GNU/Linuxの中核として、商用・非商用を問わず、再配布可能なユーティリティを収集・配布するディストリビューターが登場しました。これらのディストリビューターは、それぞれの配布物(互換性を失いがち)を、ディストリビューションとして区別する必要が生じました(特に、共有ライブラリの非互換性は目立ち、Linux支持者自身が嫌悪するWindowsのDLL-Hellに酷似しています)。 このようにして、ディストリビューション間の区別がなされたのです(また、ほかにもマーケティング上の理由などもあります)。
    Unixでディストリビューションという言葉は、ソースコードで配布されるBSDのD (distribution) と関連付けられ、一方、非ソースコード指向のGNU/Linuxディストリビューションが、Unix訴訟の間隙を利する形で386 BSDのニッチをに受入れているのは皮肉なことです。
  16. ^ Zigコンパイラーを始めとする、Zigの言語処理系とツールチェインやユーティリティーなどは、Zig自身で書かれています。
  17. ^ printf() に代表される可変引数関数は利便性は高いですが、書式化文字列と引数の型不一致が生じると、スタックフレームを非可逆的に破壊します。これを未然に防ぐことは、コンパイル時の書式化文字列の解析と引数の型情報の照合で可能ですが、コンパイル時のメモリーと計算量(≒時間)の増大に直結します。
  18. ^ Primitive Types
  19. ^ Primitive Values
  20. ^ 20.00 20.01 20.02 20.03 20.04 20.05 20.06 20.07 20.08 20.09 20.10 20.11 20.12 20.13 20.14 Grammarから抜粋。原文はPEG(Parsing Expression Grammar)なので終端子の記法などはアレンジしています。
  21. ^ 21.0 21.1 21.2 String Literals and Unicode Code Point Literals
  22. ^ Escape Sequences
  23. ^ Assignment
  24. ^ undefined
  25. ^ 25.0 25.1 25.2 Identifiers
  26. ^ この場合、文法的には if-expr(if式)ではなく if-statment(if文)になります。
  27. ^ Labeled while
  28. ^ while with Optionals
  29. ^ while with Error Unions
  30. ^ inline while
  31. ^ Labeled for
  32. ^ inline for
  33. ^ Errors
  34. ^ Error Set Type
  35. ^ 0.9.1
  36. ^ Error Union Type
  37. ^ Operators
  38. ^ Table of Operators
  39. ^ Multidimensional Arrays
  40. ^ Sentinel Terminated Arrays
  41. ^ Vectors
  42. ^ Pointers
  43. ^ volatile
  44. ^ Alignment
  45. ^ allowzero
  46. ^ Sentinel Terminated Pointers
  47. ^ Slices
  48. ^ Sentine -Terminated Slices
  49. ^ C言語の struct は、テンプレートの定義を行う構文で型にするためには、追加の typedef が必要で「構造体」がふさわしかったのですが、Zig では正確に型を定義するので「構造」あるいは「構造型」が妥当です。ここでは混乱を避けるためキーワードでもある struct としました。
  50. ^ struct
  51. ^ Anonymous Struct Literals
  52. ^ enum
  53. ^ union
  54. ^ Tagged union
  55. ^ extern union
  56. ^ packed union
  57. ^ Anonymous Union Literals
  58. ^ Casting
  59. ^ Builtin Functions
  60. ^ @addWithOverflow
  61. ^ @alignCast
  62. ^ @alignOf
  63. ^ @as
  64. ^ @asyncCall
  65. ^ @atomicLoad
  66. ^ @atomicRmw
  67. ^ @atomicStore
  68. ^ @bitCast
  69. ^ @bitOffsetOf
  70. ^ @boolToInt
  71. ^ @bitSizeOf
  72. ^ @breakpoint
  73. ^ @mulAdd
  74. ^ @byteSwap
  75. ^ @bitReverse
  76. ^ @offsetOf
  77. ^ @call
  78. ^ @cDefine
  79. ^ @cImport
  80. ^ @cInclude

外部リンク編集